      REM IMPORT-WEB
*PIC-LAN
*
*ALL
*PC
*Y
*
*
*
*
      INCLUDE SYS.TYPE.INCLUDE
*
      INCLUDE PL.COMMON
      INCLUDE PL.COMMON.DEFS
      INCLUDE PL.DEFS
      INCLUDE PLIP.COMMON
      INCLUDE PLW.COMMON
      INCLUDE PL.INIT.INCLUDE
*
      CALL PLIP.INIT.SUB
*
      OPEN 'WWW.CTRL' TO CTRL.FD ELSE CALL PLXX.STOP(201,'WWW.CTRL')
*
      S.OPT = ( INDEX(SENT<2>,'S',1) # 0 )
*
      LOC.FILE = SENT<1,2>
      HST.ROOT = SENT<1,3>
*
      PRINT 'LOC.FILE = ' : LOC.FILE
      PRINT 'HST.ROOT = ' : HST.ROOT
      PRINT 'S.OPT = ' : S.OPT
*
      OPEN LOC.FILE TO DATA.FD ELSE CALL PLXX.STOP(201,LOC.FILE)
*
      IF S.OPT THEN
         DIR.OPT = 'ND'
      END ELSE
         DIR.OPT = 'N'
      END
*
      DIR.LIST = '/'
      FNAMES = ''
      LOOP
         CALL PLHOST.DIR(HST.ROOT:DIR.LIST<1>:'*.*',DIR.OPT,DTA)
         FOR I = 1 TO DCOUNT(DTA,AM)
            FNAME = DTA<I,1>
#IFN UNIX
            FNAME = OCONV(FNAME,'MCU')
#END
            BEGIN CASE
               CASE INDEX(DTA<I,3>,'D',1)
                  IF (FNAME)[1,1] <> '_' AND FNAME <> '.' AND FNAME <> '..' THEN
                     DIR.LIST<-1> = DIR.LIST<1> : FNAME : '/'
                  END
               CASE INDEX(DTA<I,3>,'N',1)
                  FNAMES<-1> = DIR.LIST<1>[2,999] : FNAME
            END CASE
         NEXT I
         DIR.LIST = DELETE(DIR.LIST,1,0,0)
      WHILE DIR.LIST <> '' DO REPEAT
*
      FOR I = 1 TO DCOUNT(FNAMES,AM)
         FILENAME = FNAMES<I>
         PRINT I 'R#3' : ' ' : FILENAME 'L#40' : ' ' :
         IF INDEX(FILENAME,'.',1) THEN
            FILE.TP = FIELD(FILENAME,'.',DCOUNT(FILENAME,'.'))
         END ELSE
            FILE.TP = ''
         END
#IF UNIX
         FILE.TP = OCONV(FILE.TP,'MCU')
#END
         READ MIME.TP FROM CTRL.FD , 'MIME*' : FILE.TP THEN
            BEGIN CASE
               CASE MIME.TP<2> = 'HEX'
                  OPT = 'X'
                  OPT2 = 'X'
               CASE MIME.TP<2> = 'AM'
                  OPT = 'a'
                  OPT2 = 'A'
               CASE YES
                  OPT = AM
                  PRINT '   invalid MIME type encoding.' :
            END CASE
         END ELSE
            OPT = AM
            PRINT '   extension not supported.' :
         END
*
         IF OPT <> AM THEN
            CALL PLHOST.IMPORT(HST.ROOT:'/':FILENAME,OPT2,D)
#IF UNIX
            FILENAME = OCONV(FILENAME,'MCU')
#END
            WRITE D ON DATA.FD , FILENAME
         END
*
         PRINT
      NEXT I
   END
