SUBROUTINE PLW.CRUNCH.HTML(SRC,DST)
*PIC-LAN
*
*ALL
*PC
*N
*
*
*
*
******************************************************************************
******************************************************************************
***                                                                        ***
*** (C) Copyright 1990-2005 Doug Dumitru, All Rights Reserved.             ***
***                                                                        ***
*** This program is licensed under the terms of the GNU General Public     ***
*** License, version 2.0 with attached notices.                            ***
***                                                                        ***
*** The full text can be found in the LICENSE.TXT file in the              ***
*** PLIP.BP database file (the /usr/qmweb/PLIP.BP/PLIP.BP directory).      ***
***                                                                        ***
******************************************************************************
******************************************************************************
*
      INCLUDE SYS.TYPE.INCLUDE
*
      DST = ''
*
      PRE.FLG = NO
*
      LOOP WHILE SRC <> '' DO
         T = INDEX(SRC,'<',1)
         IF NOT(T) THEN
            S = SRC
            SRC = ''
            GOSUB 100
         END ELSE
            IF T > 1 THEN
               S = SRC[1,T-1]
               SRC = SRC[T,BIG.STR]
               GOSUB 100
            END
            W = OCONV(SRC[1,5],'MCL')
            BEGIN CASE
               CASE W[1,4] = '<pre'
                  PRE.FLG = YES
               CASE W[1,5] = '</pre'
                  PRE.FLG = NO
            END CASE
            DST = DST : '<'
            SRC = SRC[2,BIG.STR]
         END
      REPEAT
*
      RETURN
*
100   REM
*
      IF PRE.FLG THEN
         DST = DST : S
         RETURN
      END
*
      LOOP
         T = INDEX(S,' ':AM,1)
      WHILE T DO
         IF T > 1 THEN
            S = S[1,T-1] : S[T+1,BIG.STR]
         END ELSE
            S = S[T+1,BIG.STR]
         END
      REPEAT
*
      LOOP
         T = INDEX(S,AM:' ',1)
      WHILE T DO
         S = S[1,T] : S[T+2,BIG.STR]
      REPEAT
*
      DST = DST : S
*
      RETURN
   END